初始化提交

arduino-cli/libraries/Adafruit_MQTT_Library/examples/mqtt_fona/fonahelper.cpp

@@ -0,0 +1,57 @@
+#include "Adafruit_FONA.h"
+#include <Adafruit_SleepyDog.h>
+#include <SoftwareSerial.h>
+
+#define halt(s)                                                                \
+  {                                                                            \
+    Serial.println(F(s));                                                      \
+    while (1)                                                                  \
+      ;                                                                        \
+  }
+
+extern Adafruit_FONA fona;
+extern SoftwareSerial fonaSS;
+
+boolean FONAconnect(const __FlashStringHelper *apn,
+                    const __FlashStringHelper *username,
+                    const __FlashStringHelper *password) {
+  Watchdog.reset();
+
+  Serial.println(F("Initializing FONA....(May take 3 seconds)"));
+
+  fonaSS.begin(4800); // if you're using software serial
+
+  if (!fona.begin(fonaSS)) { // can also try fona.begin(Serial1)
+    Serial.println(F("Couldn't find FONA"));
+    return false;
+  }
+  fonaSS.println("AT+CMEE=2");
+  Serial.println(F("FONA is OK"));
+  Watchdog.reset();
+  Serial.println(F("Checking for network..."));
+  while (fona.getNetworkStatus() != 1) {
+    delay(500);
+  }
+
+  Watchdog.reset();
+  delay(5000); // wait a few seconds to stabilize connection
+  Watchdog.reset();
+
+  fona.setGPRSNetworkSettings(apn, username, password);
+
+  Serial.println(F("Disabling GPRS"));
+  fona.enableGPRS(false);
+
+  Watchdog.reset();
+  delay(5000); // wait a few seconds to stabilize connection
+  Watchdog.reset();
+
+  Serial.println(F("Enabling GPRS"));
+  if (!fona.enableGPRS(true)) {
+    Serial.println(F("Failed to turn GPRS on"));
+    return false;
+  }
+  Watchdog.reset();
+
+  return true;
+}

arduino-cli/libraries/Adafruit_MQTT_Library/examples/mqtt_fona/mqtt_fona.ino

@@ -0,0 +1,169 @@
+/***************************************************
+  Adafruit MQTT Library FONA Example
+
+  Designed specifically to work with the Adafruit FONA
+  ----> http://www.adafruit.com/products/1946
+  ----> http://www.adafruit.com/products/1963
+  ----> http://www.adafruit.com/products/2468
+  ----> http://www.adafruit.com/products/2542
+
+  These cellular modules use TTL Serial to communicate, 2 pins are
+  required to interface.
+
+  Adafruit invests time and resources providing this open source code,
+  please support Adafruit and open-source hardware by purchasing
+  products from Adafruit!
+
+  Written by Limor Fried/Ladyada for Adafruit Industries.
+  MIT license, all text above must be included in any redistribution
+ ****************************************************/
+#include <Adafruit_SleepyDog.h>
+#include <SoftwareSerial.h>
+#include "Adafruit_FONA.h"
+#include "Adafruit_MQTT.h"
+#include "Adafruit_MQTT_FONA.h"
+
+/*************************** FONA Pins ***********************************/
+
+// Default pins for Feather 32u4 FONA
+#define FONA_RX  9
+#define FONA_TX  8
+#define FONA_RST 4
+SoftwareSerial fonaSS = SoftwareSerial(FONA_TX, FONA_RX);
+
+Adafruit_FONA fona = Adafruit_FONA(FONA_RST);
+
+/************************* WiFi Access Point *********************************/
+
+  // Optionally configure a GPRS APN, username, and password.
+  // You might need to do this to access your network's GPRS/data
+  // network.  Contact your provider for the exact APN, username,
+  // and password values.  Username and password are optional and
+  // can be removed, but APN is required.
+#define FONA_APN       ""
+#define FONA_USERNAME  ""
+#define FONA_PASSWORD  ""
+
+/************************* Adafruit.io Setup *********************************/
+
+#define AIO_SERVER      "io.adafruit.com"
+#define AIO_SERVERPORT  1883
+#define AIO_USERNAME    "...your AIO username (see https://accounts.adafruit.com)..."
+#define AIO_KEY         "...your AIO key..."
+
+/************ Global State (you don't need to change this!) ******************/
+
+// Setup the FONA MQTT class by passing in the FONA class and MQTT server and login details.
+Adafruit_MQTT_FONA mqtt(&fona, AIO_SERVER, AIO_SERVERPORT, AIO_USERNAME, AIO_KEY);
+
+// You don't need to change anything below this line!
+#define halt(s) { Serial.println(F( s )); while(1);  }
+
+// FONAconnect is a helper function that sets up the FONA and connects to
+// the GPRS network. See the fonahelper.cpp tab above for the source!
+boolean FONAconnect(const __FlashStringHelper *apn, const __FlashStringHelper *username, const __FlashStringHelper *password);
+
+/****************************** Feeds ***************************************/
+
+// Setup a feed called 'photocell' for publishing.
+// Notice MQTT paths for AIO follow the form: <username>/feeds/<feedname>
+Adafruit_MQTT_Publish photocell = Adafruit_MQTT_Publish(&mqtt, AIO_USERNAME "/feeds/photocell");
+
+// Setup a feed called 'onoff' for subscribing to changes.
+Adafruit_MQTT_Subscribe onoffbutton = Adafruit_MQTT_Subscribe(&mqtt, AIO_USERNAME "/feeds/onoff");
+
+/*************************** Sketch Code ************************************/
+
+// How many transmission failures in a row we're willing to be ok with before reset
+uint8_t txfailures = 0;
+#define MAXTXFAILURES 3
+
+void setup() {
+  while (!Serial);
+
+  // Watchdog is optional!
+  //Watchdog.enable(8000);
+  
+  Serial.begin(115200);
+
+  Serial.println(F("Adafruit FONA MQTT demo"));
+
+  mqtt.subscribe(&onoffbutton);
+
+  Watchdog.reset();
+  delay(5000);  // wait a few seconds to stabilize connection
+  Watchdog.reset();
+  
+  // Initialise the FONA module
+  while (! FONAconnect(F(FONA_APN), F(FONA_USERNAME), F(FONA_PASSWORD))) {
+    Serial.println("Retrying FONA");
+  }
+
+  Serial.println(F("Connected to Cellular!"));
+
+  Watchdog.reset();
+  delay(5000);  // wait a few seconds to stabilize connection
+  Watchdog.reset();
+}
+
+uint32_t x=0;
+
+void loop() {
+  // Make sure to reset watchdog every loop iteration!
+  Watchdog.reset();
+
+  // Ensure the connection to the MQTT server is alive (this will make the first
+  // connection and automatically reconnect when disconnected).  See the MQTT_connect
+  // function definition further below.
+  MQTT_connect();
+
+  Watchdog.reset();
+  // Now we can publish stuff!
+  Serial.print(F("\nSending photocell val "));
+  Serial.print(x);
+  Serial.print("...");
+  if (! photocell.publish(x++)) {
+    Serial.println(F("Failed"));
+    txfailures++;
+  } else {
+    Serial.println(F("OK!"));
+    txfailures = 0;
+  }
+
+  Watchdog.reset();  
+  // this is our 'wait for incoming subscription packets' busy subloop
+  Adafruit_MQTT_Subscribe *subscription;
+  while ((subscription = mqtt.readSubscription(5000))) {
+    if (subscription == &onoffbutton) {
+      Serial.print(F("Got: "));
+      Serial.println((char *)onoffbutton.lastread);
+    }
+  }
+
+  // ping the server to keep the mqtt connection alive, only needed if we're not publishing
+  //if(! mqtt.ping()) {
+  //  Serial.println(F("MQTT Ping failed."));
+  //}
+
+}
+
+// Function to connect and reconnect as necessary to the MQTT server.
+// Should be called in the loop function and it will take care if connecting.
+void MQTT_connect() {
+  int8_t ret;
+
+  // Stop if already connected.
+  if (mqtt.connected()) {
+    return;
+  }
+
+  Serial.print("Connecting to MQTT... ");
+
+  while ((ret = mqtt.connect()) != 0) { // connect will return 0 for connected
+    Serial.println(mqtt.connectErrorString(ret));
+    Serial.println("Retrying MQTT connection in 5 seconds...");
+    mqtt.disconnect();
+    delay(5000);  // wait 5 seconds
+  }
+  Serial.println("MQTT Connected!");
+}